Syntax

As you've seen in the earlier chapter, Pascal programs have a standard structure which looks like the following:

Program program_name;

{ Global variables }
Var
 A_Variable: Variable_Type;

{ Other functions/procedures }

Procedure SayHello;

 { Local variables }
 Var
  T : String;

 Begin
  { Redundant code to illustrate the use of local variables in a procedure }
  T := 'Hello'; 
  Writeln(T);
 End;

{ Main function }

Begin
 { Do something }
 SayHello;
End.

A program has a program header, followed by global variable definitions, procedure or function definitions and finally the main function.

A_Variable,Another_Variable ... : Variable_Type;

a,b : integer;
c : integer;
d,e : string;
f : real;
g : extended;
h,i,j,k : byte;
l,m,n,o : byte;

Functions/Procedures

Before we begin, let us first clarify the key difference between functions and procedures. A procedure is set of instructions to be executed, with no return value. A function is a procedure with a return value. For readers familiar with C/C++, a procedure is simply a function with a void return value, as in void proc_sayhello().

The definition of function/procedures is thus as such:

Function Func_Name(params...) : Return_Value;
Procedure Proc_Name(params...);

The function/procedure definition is usually followed by the local variables and the body. However, to provide prototypes, simply add a forward keyword behind the definition instead of the local variables and the body. Of course, the whole function must be defined somewhere else in the program. The following example illustrates the use of this:

Function Add(A, B : Integer): Integer; Forward;

Function Bad(A, B, C : Integer) : Integer;

Begin
 Bad := Add(Add(A,B),C);
End;

Function Add(A, B : Integer) : Integer; 
Begin
 Add := A + B;
End;

In this example, Add is first defined as a function taking two integer variables and returning an integer, but it is defined as a forward definition (prototype), and thus no body is written. Later, we see that Add is defined with a body. Note that the two definitions of Add must be congruent with each other, or the compiler will complain.

From the above example, we can also gather that in Pascal, a function's return value is given by the value of the variable with the function's name (or by the variable named result), when the function returns. As you can see in the Bad function, an undefined variable named "Bad" has been assigned a value. That is the return value for the Bad function. Similarly, in Add, the variable named "Add" has been assigned a value, which is its return value.

Note that unlike C or other languages, assigning a return value to a function does not return from the function. Thus, the function will continue executing, as in the following example:

Function Weird(A : Integer) : Integer;

Var
 S : Integer;

Begin
 S := A/2;

 If S < 10 Then
  Weird := 1;

 S := S + 9;

 If S >= 10 Then
  Weird := 0;

 Weird := 2;
End;

If A happens to be 6, the function will not return the expected result of 1 or even 0. Instead, it would return a result of 2, because the function to execute continues even after the return value is set. In fact, as you would notice, the function would return 2 all the time because it runs all the way to the end, at which the return value is set to 2.

To mimic C style function returns, the exit statement must be used. The exit statement in Pascal, unlike C, exits from the current block of code (in this case, the function), and NOT from the program. The code would then look like this:

Function Weird(A : Integer) : Integer;

Var
 S : Integer;

Begin
 S := A/2;

 If S < 10 Then
 Begin
  Weird := 1;
  Exit;
 End;

 S := S + 9;
 
 If S >= 10 Then
 Begin
  Weird := 0;
  Exit;
 End;

 Weird := 2;
End;

Note that a third exit is not necessary at the end of the function since nothing else would be executed that could overwrite the function return.